
. REVERSE

   1 .
   2 . REVERSE
   3 . BY ROB ROSENHOUSE
   4 . FOR SUPER SOFTWARE
   5 .
   6 . (C) 1981
   7 .
   8 .
   9 :RETURN ;NT=0;BC=50;FC=7;GOSUB 1000;P=48;GOTO 90
  10 GOSUB 200
  11 GOSUB 30;S=S+1;CX=40;CY=32;PRINT #2,S
  12 RETURN 
  20 FOR A=1TO 20;@(A)=0;NEXT A
  21 FOR A=1TO 9
  22 B=RND (9);IF @(B+10)GOTO 22
  23 @(A)=B;@(B+10)=1;NEXT A;RETURN 
  30 CY=-8;CX=-53;FOR A=1TO 9;PRINT #2,@(A),;NEXT A;RETURN 
  40 GOSUB 20;X=-65;Y=0;FOR A=1TO 9;FOR B=1TO 12;X=X+1;CX=X;CY=Y;PRINT " *",;NT=1;MU="*";NT=0
  41 NEXT B;CX=X;CY=-8;PRINT #2,@(A),;NEXT A
  42 X=X+1;CX=X;CY=Y;PRINT " *",
  43 IF X=70CX=X;PRINT "  ";RETURN 
  44 NT=1;GOTO 42
  90 CLEAR ;GOSUB 20;GOSUB 30;T=0;S=0
  95 CY=40;CX=-54;PRINT "TIME          TURNS";CY=32;CX=40;PRINT #2,0
  96 X=0;Y=0
 100 T=T+1;CX=-48;CY=32;PRINT #2,T,
 105 BOX X,Y,3,3,2;NT=2;MU=P;NT=0;IF RND (100)=1GOSUB 40
 106 P=P+1;IF P>88P=49
 110 X=X+JX(1)×12;IF X>48X=48
 115 IF X<-48X=-48
 120 BOX X,Y,3,3,1
 140 IF TR(1)GOSUB 10
 150 FOR A=1TO 9;IF @(A)=ANEXT A;GOTO 300
 160 A=9;NEXT A
 190 GOTO 100
 200 N=X÷12+5
 210 FOR A=1TO N÷2
 220 W=@(A);@(A)=@(N-A+1);@(N-A+1)=W
 230 NEXT A;RETURN 
 300 &(21)=31;FOR A=50TO 0STEP -1;BOX 0,-8,160,10,3;&(19)=A×2;NEXT A;&(21)=0
 500 IF T<GGOSUB 600;G=T
 510 IF S<HGOSUB 650;H=S
 520 GOTO 700
 600 CLEAR ;PRINT "YOUR TIME IN THIS GAME IS THE BEST TODAY.  PLEASE   ENTER YOUR 3 INITIALS:
 605 CX=-12;CY=0;FOR A=21TO 23;BOX CX,CY,7,8,1;K=KP;IF K=31GOTO 605
 610 @(A)=K;TV=K;NEXT A;RETURN 
 650 CLEAR ;PRINT "THE NUMBER OF TURNS WHICH YOU USED IN THIS GAME IS  THE LOWEST USED TODAY.
 655 PRINT "PLEASE ENTER YOUR THREE   INITIALS:
 660 CX=-12;CY=0;FOR A=24TO 26;BOX CX,CY,7,8,1;K=KP;IF K=31GOTO 660
 670 @(A)=K;TV=K;NEXT A;RETURN 
 700 CLEAR ;CX=-33;PRINT "BEST SCORES:
 705 CY=24;CX=-30;PRINT "LOWEST TIME:
 710 PRINT "         ",#3,G,"  ",;FOR A=21TO 23;TV=@(A);NEXT A
 715 CY=0;CX=-54;PRINT "LEAST NO. OF TURNS:
 720 PRINT "         ",#3,H,"  ",;FOR A=24TO 26;TV=@(A);NEXT A
 730 FOR A=1TO 250;IF &(23)GOTO 90
 740 NEXT A
 750 CLEAR ;PRINT "GO FROM:";GOSUB 20
 760 CY=24;CX=-55;FOR A=1TO 9;PRINT #2,@(A),;NEXT A
 770 CY=0;CX=-80;PRINT "TO:";FOR A=1TO 300;NEXT A;CX=-55;CY=-16
 775 FOR A=1TO 9;PRINT #2,A,;NEXT A
 780 FOR A=1TO 250;IF &(23)GOTO 90
 790 NEXT A;CLEAR ;CX=-21;CY=0;PRINT "REVERSE!
 795 CY=-32;CX=-48;PRINT "BY ROB ROSENHOUSE
 800 BOX 0,0,160,12,3;FOR A=1TO 20;BOX 0,0,50,10,3
 810 FOR B=1TO 20;IF &(23)GOTO 90
 820 NEXT B;NEXT A;GOTO 700
1000 G=RND (250)+425;H=RND (25)+34;FOR A=21TO 26;@(A)=RND (26)+64;NEXT A;RETURN 

:RETURN 
>